왕미친놈의 왕미친세상

들어가며

IF 명령 확장은 IF 명령이 가진 기능을 추가하고 넓힌다는 뜻으로, IF 명령으로 여러 가지 다른 처리를 할 수 있도록 해 준다. 앞서 나온 IF 문자열에서도 일부 소개하였지만, 윈도XP의 IF 명령은 상당히 뛰어난 기능을 제공하고 있다. 대부분 IF 문자열 기능에 포함되어 있고, 여기에서는 IF 문자열에서 설명하지 않은 부분만을 설명하겠다.

말뜻

IF 명령 확장에는 세 문자로 이루어진 비교 연산자(연산자 확장)와 IF CmdExtVersion 구문 및 IF Defined 구문이 있다.

• 세 문자로 이루어진 비교 연산자는 IF 문자열을 참조하세요.
• IF CmdExtVersion 수 : 윈도XP의 도움말 및 지원 센터의 설명에 따르면, Cmd.exe의 명령 확장 기능과 관련된 내부 버전 번호가 '수'보다 크거나 같은 경우에만 참인 조건을 지정합니다. 첫째 버전은 '1'이며 의미있는 향상을 명령 확장에 추가할 때 하나씩 증가합니다. 명령 확장을 사용할 수 없게 설정하면 CmdExtVersion 조건은 항상 거짓입니다. 명령 확장이 사용 가능한지를 검사할 때도 사용할 수 있습니다. CmdExtVersion의 정확한 값을 알고 싶다면 명령행에서도 "echo %CmdExtVersion%"라고 입력해 보라.
• IF Defined 환경변수 : 지정한 환경변수가 정의되어 있으면 참값을, 그렇지 않으면 거짓값을 돌려준다.

IF CmdExtVersion 구문

명령확장을 사용할 수 있는지를 사용할 수 있다. 또한 명령확장의 버전을 검사하여 배치파일 실행 여부를 판단할 때도 쓸 수 있다.

1. if CmdExtVersion 2 (
2. echo 윈도XP에서 명령확장을 사용할 수 있습니다.
3. ) else echo 윈도XP가 아니거나 명령확장을 사용할 수 없습니다.

위와 같은 형식이 가장 기본적이다. echo 문은 예시일 뿐이니, 저 부분에 자신이 실행하기를 바라는 명령을 넣으면 된다.

또한 단순히 명령확장을 사용할 수 있는지를 알려면 다음과 같이 하면 된다.

1. if CmdExtVersion 0 (
2. echo 명령확장을 사용할 수 있습니다.
3. ) else echo 윈도NT 계열이 아니거나 명령확장을 사용할 수 없습니다.

명령확장을 사용할 수 있다면 "if CmdExtVersion 0"은 무조건 참이 되어야 하므로 위의 예제는 명령확장을 사용할 수 있는지를 검증해 주는 코드가 된다.

IF Defined 구문

IF Defined 구문은 IF 문자열 구문의 확장으로 볼 수 있다.

1. if not * == %var%* echo Variable %var% is defined.
2. if not * == %var%* echo 환경변수 %var%이(가) 정의되어 있습니다.

위 두 문장은 출력문만 다를 뿐 완전히 같다. 환경변수가 정의되어 있다면 항상 문자열 값을 가지게 되므로 위의 구문에서 참값을 가지게 된다. 결국 "환경변수 %var%이(가) 정의되어 있습니다."라고 출력한다는 뜻이다. 이때 *(별표) 대신 다른 문자를 사용해도 결과는 같으나, %, ^, & 등은 사용하지 않는 것이 좋다. 특히 %와 ^는 배치파일에서 특별한 작용을 하므로 if문에 사용했을 경우 그 효과를 정확히 알고 사용해야 한다.

위의 예제를 Defined 를 이용하여 고치면 다음과 같다.

1. if Defined %var% echo Variable %var% is defined.
2. if Defined %var% echo 환경변수 %var%이(가) 정의되어 있습니다.

if Defined 환경변수 구문을 이용하게 되면 세 환경변수―%errorlevel%, %cmdcmdline% 및 %cmdextversion%―를 사용할 수 있게 됩니다. %errorlevel% 환경변수는 마지막으로 실행한 프로그램이 돌려주는 종료코드를 저장하고, %cmdcmdline% 환경변수는 마지막으로 실행한 명령줄을 저장합니다. 그리고 %cmdextversion% 환경변수는 앞서 설명했듯이 명령확장의 버전을 저장하고 있습니다.

과제

지난 번 과제는 다음 구문을 옳게 고치라는 문제였습니다.

1. rem Compare.cmd
2. IF /i NOT %1 EQU %2 ECHO %1 is equal %2 ELSE ECHO %1 is not equal %2 .

아래와 같이 하면 된다. 빨간 색 부분을 유심히 살펴보기 바란다.

1. rem Compare.cmd
2. IF /i %1 EQU %2 ( ECHO %1 is equal %2 ) ELSE ECHO %1 is not equal %2 .

다음 예고

GOTO문을 설명하기에 앞서 잠시 쉬어가는(?) 시간을 갖도록 하자. 다음에는 환경변수에 대해서 알아보겠다.

이 글은 스프링노트에서 작성되었습니다.

들어가며

IF 문자열 비교 구문은 말 그대로 문자열을 비교하는 구문이다. 이것은 윈도NT 계열에서 추가된 환경 변수 등을 이용하여 여러 가지 작업을 할 수 있도록 해준다. 문자열의 내용을 분석하여 정수(십진수, 팔진수, 십육진수)로 변환하여 계산해 주기도 한다.

말뜻

IF 문자열 비교 구문에서는 일반적으로 등호를 두 개 겹쳐서 쓰게 된다.

1. if [not] 문자열1==문자열2 명령 [else 구문]

위와 같은 형식을 이루게 된다. 이때 큰괄호( [ ] )로 묶인 부분은 반드시 쓸 필요는 없고 필요할 때 쓰면 된다. 또한 문자열에 공백을 포함하지 않았다면 따옴표를 사용하지 않아도 된다.

문자열 비교 구문의 명령 확장

확장 1

명령 확장이라고 말하기는 했으나, 사실 /i 선택자는 cmd.exe에 포함된 if 명령에서는 기본 선택자이다. 다만 도스의 if 명령과 호환성이 없기 때문에 확장이라고 칭했을 뿐이다.

문자열 비교 구문에서 /i 선택자를 쓰게 되면 그 기능을 확장할 수 있다. 이것은 대문자와 소문자를 무시하고 문자열을 비교하게 됩니다.

1. IF STRING==string ECHO STRING is string.

위의 문자열 비교 구문은 거짓을 돌려주므로 화면에 아무것도 보여주지 않는다. 그러나 아래 문자열 비교 구문은 참을 돌려주므로 화면에 "STRING is string."이라는 문자열을 출력해 준다.

1. IF /i STRING==string ECHO STRING is string.

확장 2

문자열 비교 구문에서는 세 문자로 이루어진 비교 연산자를 사용할 수 있다. 이것은 /i 선택자를 사용하여 융통성을 가지는데, 예컨대 숫자로만 이루어진 문자열은 수로 변환하여 비교해 준다.

세 문자로 이루어진 비교 연산자에는 다음과 같은 것이 있다.

• EQU (같음)
• NEQ (같지 않음)
• LSS (보다 작음)
• LEQ (작거나 같음)
• GTR (보다 큼)
• GEQ (크거나 같음)

비교 연산자는 언뜻 보아서는 숫자로 이루어진 문자열에만 쓰일 듯이 보이지만 로마자 등으로 이루어진 문자열에도 쓰일 수 있다.

예제 1

1. IF /i 22 EQU 026 ECHO 22 is 026.

위의 코드는 10진수 22와 8진수 026을 비교하는 구문이다. 당연히 두 값은 크기가 같으므로 화면에 문자열을 출력해 준다.

1. IF /i 026 EQU 0X16 ECHO 026 is 0X16.

위의 코드는 8진수 026과 16진수 0x16을 비교하는 구문이다. 당연히 두 값은 크기가 같으므로 화면에 문자열을 출력해 준다. 

두 예제는 /i 선택자가 문자열을 확장하여 "일반적으로 해석"하는 예시이다. 다시 말해 문자열 22는 10진수 22로 해석해 주며, 026은 8진수로, 0x16은 16진수로 해석해 준다. 10진수는 0으로 시작할 수 없으며, 0으로 시작하는 수는 8진수이거나 16진수가 된다. 또한 0으로 시작하는 문자열 가운데 0x로 시작하는 문자열은 16진수로 여기게 된다.

하지만 089 등의 문자열은 올바르지 않으므로 오류가 발생하게 된다. 이는 8진수에 8과 9와 같은 숫자는 존재하지 않기 때문이다. 마찬가지로 0x9G 등의 문자열도 올바르지 않다고 여긴다. 이럴 경우 문자열을 수로 확장해 주지 않고, 문자열 자체(리터럴 문자열)로서 비교하게 된다. 참고로 순수한 문자열을 리터럴 문자열(literal string), 수치로서 변환되는 문자열을 숫자 문자열(number string / numeric string)이라고 부른다.

한편 다음에 오는 두 비교문은 서로 다른 결과를 가진다.

1. IF /i 22 EQU 026 ECHO 22 is 026.

위의 비교문은 수치 비교문으로 참값을 돌려주므로 "22 is 026."을 출력한다.

1. IF /i 22 == 026 ECHO 22 is 026.

위의 비교문은 리터럴 문자열 비교문으로 거짓값을 돌려주므로 아무것도 출력하지 않는다.

다시 말해 숫자로 이루어진 문자열을 숫자 문자열로서 비교하려면 반드시 문자로 이루어진 비교 연산자를 사용해야 한다.

또한 다음과 같이 사용할 수도 있다.

1. IF /i abc EQU ABC ECHO abc is ABC.

또는

1. IF /i NOT abc EQU ABC ( ECHO abd is ABC ) ELSE ECHO abd is not ABC .

앞서 말했듯이 세 문자로 이루어진 비교 연산자로 숫자 문자열뿐만 아니라 리터럴 문자열까지 비교할 수 있다.

1. IF /i abc NEQ ABC ( ECHO abd is ABC ) ELSE ECHO abd is not ABC .

위의 비교문도 정상 작동한다.

예제 2

그렇다면 작거나 같음을 비교할 때는 어떻게 동작할까? LSS (보다 작음), LEQ (작거나 같음), GTR (보다 큼), GEQ (크거나 같음)과 같은 세 문자로 이루어진 비교 연산자를 이용하여 대문자와 소문자를 비교해 보자,

1. IF /i 22 LSS 027 ECHO 22 is less than 027.

위 예제는 10진수 22가 8진수 027보다 작으면 뒤따르는 문자열을 출력하라는 문자열 비교문입니다.

그러면 다음과 같은 두 가지 예문은 어떻게 작동할까?

1. IF /i abc LSS ABC ECHO abc is less than ABC.
2. IF abc LSS ABC ECHO abc is less than ABC.

우선 1행은 아무런 출력이 없다. 왜냐하면 /i 선택자 때문에 대문자와 소문자를 무시하고 비교했기 때문이다. 그러나 2행은 소문자 abc가 대문자 ABC보다 더 작은 값으로 해석되어 문자열 "abc is less than ABC."을 출력해 준다.

1. IF ABC GTR abc ECHO ABC is greater than abc.

마찬가지로 위의 코드는 대문자 ABC가 소문자 abc보다 더 큰 값으로 해석되어 "ABC is greater than abc."라는 문자열을 출력해 준다.

위와 같이 대문자와 소문자 비교에서 대문자가 소문자보다 더 크다고 판정함을 알 수 있다.

예제 3

그 다음으로 문자간 비교를 해볼 수 있다.

1. IF d GTR a ECHO D is greater than A.

위의 예제는 문자여을 출력해 준다. 다시 말해 문자열 d가 문자열 a보다 더 큰 값을 가진다고 판단함을 알 수 있다. 반대로 아래와 같은 비교문도 성립한다.

1. IF a LSS d ECHO a is less than d.

로마자 알파벳을 비교할 때 순서가 빠른 문자를 더 작다고 판단함을 알 수 있다.

1. IF 가 LSS 나 ECHO 가 is less than 나.

한글 문자열을 비교할 때도 성립한다.

1. IF 가 LSS d ECHO 가 is less than d.

한글을 로마자보다 더 작다고 판정하고 있다.

과제

아무도 검사하지 않는 과제가 또 나왔습니다. 헤헤 ^^a

1. rem Compare.cmd
2. IF /i NOT %1 EQU %2 ECHO %1 is equal %2 ELSE ECHO %1 is not equal %2 .

위의 배치 파일이 정상적으로 작동하도록 고쳐 보자.

다음 예고

IF 명령을 하나씩 짚어보자. (4) : IF 명령확장

이 글은 스프링노트에서 작성되었습니다.

들어가며

IF EXIST 구문은 단순히 어떤 디렉터리나 파일이 존재하는지를 알려줄 뿐이다. 응용하기에 따라서는 상당히 유용한 기능을 제공한다. 또한 속성의 영향을 받지 않기 때문에 숨김 속성의 파일이나 시스템 속성의 파일도 찾아낼 수 있다. 또한 윈도 탐색기에서 접근하지 못하도록 레지스트리 등을 조작하여 감춰둔 드라이브도 접근할 수 있다.

IF EXIST 구문에는 기본 문법 외에 명령 확장이 존재하지 않는다. 정확히 말해 명령 확장을 이용할 수는 있지만, 그와 같은 명령 확장은 if 명령 전체에 적용되는 명령 확장이고, IF EXIST 구문에만 쓰이는 명령 확장이 아니다. 또다른 명령 확장으로 set 명령 확장이 있으나, 이것 역시 IF EXIST 구문에만 쓰이는 명령 확장이 아니다. 그러므로 여기에서는 설명하지 않겠다.

말뜻

EXIST는 말 그대로 "있다" 또는 "존재한다"라는 뜻을 가지고 있다. 그러므로 IF EXIST 구문은 무엇인가가 존재하는지를 묻는 구문이 된다. 존재하면 참값을, 존재하지 않으면 거짓값을 돌려준다.

예제

실제로 적용하기에는 무리가 있지만, 간단한 배치파일을 작성하였다.

1. @echo off
2. rem 파일명 : ExistSys.bat
3. rem 지은이 : koc2000/SALM
4. rem 저작권 : GPL v3
5.  
6. rem 예제 13.
7. rem SYSTEM 파일로 운영체제를 가리는 배치파일
8. rem 사용법 : ExistSys
9.  
10. rem c:\ 디렉터리에 존재하는 파일에 따라 시스템을 판별한다.
11. IF EXIST c:\ntldr GOTO :WinNT
12. IF EXIST c:\io.sys GOTO :DOS
13.  
14. :WinNT
15. echo The system is Windows NT/2000/XP.
16. goto :END
17.  
18. :DOS
19. echo The system is DOS or Windows 95/98/ME.
20. goto :END
21.  
22. :END

예제 13은 C 드라이브 루트디렉터리에 있는 파일을 기준으로 운영체제를 판별하는 배치파일이다. 이 배치파일은 정확한 동작을 보장하지 않지만, 대부분의 경우 올바르게 작동한다. 따라서 실제로 이용하기에는 무리가 있으나, 파일 존재 구문(IF EXIST 구문)을 시험하기에는 안성맞춤이다.

위에서 IF EXIST 구문이 두 번 나오는데, 순서를 바꾸면 오류가 난다. 왜냐하면 윈도XP를 비롯한 윈도NT 계열의 운영체제에도 C 드라이브 루트디렉터리에 io.sys와 msdos.sys, config.sys 및 autoexec.bat 파일이 존재하기 때문이다. 이것은 윈도95 계열에서도 마찬가지로 존재한다. 그러므로 윈도NT 계열에서만 존재하는 파일을 찾아야 하는데, 그것이 ntldr(NT Loader) 파일이다. 따라서 위의 배치파일은, 엄밀히 말해, 윈도NT 계열과 비윈도NT 계열을 판별하는 배치파일인 셈이다. 이때 io.sys 파일과 ntldr 파일이 숨김 속성과 시스템 속성을 함께 가지고 있지만, 문제 없이 접근하고 있다.

그러나 PC-DOS의 경우 위의 배치파일은 정상 작동하지 않는다. 왜냐하면 PC-DOS에서는 io.sys 파일 대신에 ibmio.sys 파일이 존재하기 때문이다. 그에 대한 적용은 여러분이 직접 해 보기 바란다.

감춰둔 폴더 접근

폴더 감추기는 윈도 셸인 탐색기에 적용되는 사항으로, cmd.exe 명령에는 적용되지 않는다. 또한 탐색기에서 모습을 찾을 수 없도록 감추었을 뿐 정확한 경로를 알고 있다면 얼마든지 사용할 수 있다.

오른쪽은 원래의 드라이브 구성이고, 왼쪽은 윈도 레지스트리를 조작하여 감춘 구성이다.

이 경우 주소표시줄에 직접 D:\ 와 같이 입력하면 D 드라이브의 루트 폴더에 접근할 수 있다. 앞서 말했듯이 감춰두었을 뿐 막은 게 아니기 때문이다. 그러나 사람들은 눈에 안 보이면 사용하지 못한다고 여기기 때문에 이렇게 드라이브를 감추는 작업은 유용할 때가 많다.

한편 명령 프롬프트에서는 애초에 모든 드라이브가 감춰진 상태이다.

달랑 자신의 홈디렉터리만 보여준다. 홈디렉터리는 유닉스 계열이나 명령 프롬프트에서 쓰는 개념이고, 윈도에서는 프로필폴더이다. 명령 프롬프트에서 다음과 같이 입력하면 된다.

1. cd %USERPROFILE%

USERPROFILE 환경 변수에 자신의 홈디렉터리(프로필폴더)에 대한 정보를 가지고 있다. 정확히 어디인지를 보려면 다음과 같이 입력하면 된다.

1. echo %USERPROFILE%

그밖에 HOMEDRIVE, HOMEPATH 등의 환경변수가 지정되어 있다. 위의 경우 홈드라이브(HOMEDRIVE)는 D: 문자열이, 홈패스(HOMEPATH)는 \Usr\LCP 문자열이 지정되어 있으며, 명령 프롬프트에서 set 명령을 입력하면 확인할 수 있다.

보통의 경우 USERPROFILE 환경 변수는 C:\Documents and Settings\USERNAME 문자열을 가지게 된다. 이때 이탤릭체로 표시한 USERNAME은 사용자마다 다르다.

아무튼 위의 두 "내 컴퓨터" 화면처럼 존재하는 폴더를 감추더라도 명령 프롬프트에서는 무리 없이 접근할 수 있다. 이것을 이용하는 것은 여러분의 몫이다.

다음 예고

• IF 명령을 하나씩 짚어보자. (3) : IF 문자열

이 글은 스프링노트에서 작성되었습니다.

들어가며

IF ERRORLEVEL문은 방금 실행을 마친 프로그램의 종료코드(마침코드)를 비교하여 프로그램 수행을 결정하는 구문이다. 이를 위해 몇 가지 프로그램의 종료코드를 소개하고자 한다. 또한 이러한 종료코드는 ERRORLEVEL 환경변수(%ERRORLEVEL%)에 저장하여 이용할 수도 있다.

말뜻

종료코드(마침코드)는 프로그램이 수행 과정에서 어떻게 처리하였는지를 알려주는 정수를 가리킨다. 주로 정수 0은 정상 종료되었음을 뜻하면 1보다 크거나 같은 값은 오류가 발생했음을 뜻한다. 프로그램이 종료하면서 운영체제에 넘겨주기 때문에 종료코드라는 이름이 붙었다.

여러 프로그램의 종료코드

윈도XP의 도움말 및 지원 센터의 내용에 따르면 다음과 같은 종료코드를 가지고 있다고 한다.

• diskcomp : 두 플로피디스크를 비교하는 명령어

  • 0 : 두 플로피디스크가 같다. (정상 종료)
  • 1 : 차이를 발견했다.
  • 2 : 하드웨어 오류 발생.
  • 3 : 초기화 오류 발생.

• xcopy : 하위 디렉터리와 파일을 복사하는 명령어

  • 0 : 파일이 오류 없이 복사됨. (정상 종료)
  • 1 : 복사할 파일을 찾지 못하다.
  • 2 : 사용자가 Ctrl+C를 눌러 강제 종료.
  • 4 : 초기화 오류가 발생. 메모리나 디스크 공간 부족, 명령줄에 잘못된 드라이브 이름이나 잘못된 구문을 입력했을 때 생긴다.
  • 5 : 디스크 쓰기 오류가 발생했습니다.

• color : 전경색(글자색)과 배경색을 지정하고 복원하는 명령어

  • 0 : 전경색과 배경색이 다르다.
  • 1 : 전경색과 배경색이 같다.

• diskcopy : 플로피디스크에서 다른 플로피디스크로 복사하는 명령어

  • 0 : 복사 성공. (정상 종료)
  • 1 : 치명적이지 않은 읽기/쓰기 오류가 발생
  • 3 : 치명적인 하드웨어 오류가 발생
  • 4 : 초기화 오류가 발생

• format : 디스크를 초기화하는 명령어

  • 0 : 포맷을 성공했습니다.  (정상 종료)
  • 1 : 잘못된 매개 변수를 입력
  • 4 : 치명적인 오류가 발생 (0, 1 또는 5를 제외한 오류).
  • 5 : "포맷을 실행하시겠습니까(Y/N)?" 메시지에서 N 키를 눌러 실행이 중단됨.

• graftabl : 그래픽 모드에서 확장 문자 집합을 표시하는 기능을 사용 가능하게 설정합니다.

  • 0 : 문자 집합을 기억장치에 읽어들이는 데 성공. 이전 코드 페이지는 로드되지 않는다. (정상 종료)
  • 1 : 잘못된 매개 변수. 작업이 수행되지 않는다.
  • 2 : 파일 오류가 발생

• replace : 대상 디렉터리의 파일을 이름이 같은 원본 디렉터리의 파일로 바꾼다. replace를 사용하여 대상 디렉터리에 고유 파일 이름을 추가할 수도 있다.

  • 0 : replace 명령이 성공적으로 파일을 바꾸거나 추가했습니다. (정상 종료)
  • 1 : replace 명령이 맞지 않는 MS-DOS 버전을 발견했습니다.
  • 2 : replace 명령이 원본 파일을 찾을 수 없습니다.
  • 3 : replace 명령이 원본이나 대상 경로를 찾을 수 없습니다.
  • 5 : 사용자는 바꾸고자 하는 파일을 액세스할 수 없습니다.
  • 8 : 명령을 실행할 시스템 메모리가 부족합니다.
  • 11 : 명령줄에 잘못된 구문을 사용했습니다.

• 그밖에 마이크로소프트 제품의 setup.exe 프로그램 : 윈도용 애플리케이션의 설치 프로그램

  • 0 : 프로그램 설치를 성공 또는 사용자가 취소한 경우. (정상 종료)
  • 0 이외의 값 : 프로그램 설치 도중에 프로그램 오류 발생

• 고스트 등의 시만텍 사의 프로그램

  • 0 : 오류가 발생하지 않고 정상 종료
  • 0 이외의 값 : 오류가 발생

예제 1

IF ERRORLEVEL문과 ELSE를 함께 사용한 예제는 GBackup1H2P.cmd 파일이다. 지난번에 작성한 GBackup1H2P.cmd을

GBackup1H2P-1.cmd로 이름을 바꾸어 저장하고, GBackup1H2P.cmd을 편집해 보자.

1. GHOST.exe -CLONE,MODE=PDUMP,SRC=1:1,DST=1:2\GHOST.GHO -Z9 -AUTO -SURE -RB
2.  
3. REM IF-ELSE 구문 : 오류가 발생하면 오류 발생을 알려준다.
4. IF ERRORLEVEL 1 (
5.     ECHO ##############################################
6.     ECHO ##      백업 도중 오류가 발생했습니다.      ##
7.     ECHO ##############################################
8. ) ELSE (
9.     ECHO ##############################################
10.     ECHO ##    백업 작업을 정상적으로 마쳤습니다.    ##
11.     ECHO ##############################################
12. )

바뀐 부분만 나타내면 위와 같다. 이때 IF는 '('와 같은 명령줄에 있어야 하며, ')'와 ELSE가 같은 명령줄에 있어야 한다. 또한 ELSE는 뒤따르는 '('와 같은 명령줄에 있어야 한다.

• 참고 : 앞서 말했듯이 위 코드는 정상 작동하지 않는다. 다만 ERRORLEVEL 검사는 잘 된다.

예제 2

XCOPY를 이용한 백업 유틸리티를 제작해 보았다.

1. @echo off
2. rem 파일명 : Xback.bat
3. rem 지은이 : koc2000/SALM
4. rem 저작권 : GPL v3
5.  
6. rem 예제 12.
7. rem XCOPY를 이용한 백업
8. rem 사용법 : Xback  원본디렉터리  대상디렉터리
9.  
10. rem 작업 1 : 매개변수가 있는가? 없으면 도움말을 보여준다.
11. IF NOT * == %2* (
12.     REM 매개변수가 모두 있으면 작업을 시작한다.
13.     REM XCOPY 명령을 이용해 백업합니다.
14.     XCOPY %1 %2 /i /S /E /H /M
15.  
16.     REM 종료코드가 4 또는 그보다 크면
17.     IF ERRORLEVEL 4 (
18.         echo 파일을 백업하기에는 메모리가 부족하거나
19.         echo 드라이브가 잘못 지정되었거나 명령줄 구문이 틀립니다.
20.     ) ELSE IF ERRORLEVEL 2 (
21.         echo 사용자가 CTRL+C를 눌러 백업 작업을 강제 종료했습니다.
22.     ) ELSE IF ERRORLEVEL 0 (
23.         echo 백업을 정상적으로 성공했습니다.
24.     )
25. ) ELSE (
26.     REM 매개변수가 없으면 메시지를 보인 뒤 사용법을 보여준다.
27.  
28.     ECHO 매개변수가 없거나 모자랍니다.
29.     ECHO 구문 : Xback  source_dir  backup_dir
30. )
31.  
32. :END

위 구문에서 11행의 " IF NOT * == %2* ( " 부분은 문자열 비교문에서 다시 설명하기로 한다.

또한 위의 코드에서 ERRORLEVEL 값이 큰 값부터 차례대로 낮아지게 만드는 것이 배치파일에서는 묵시적 원칙입니다. 이는 실수로 일어날 수 있는 오류를 막기 위한 방법이지요. 왜냐하면 IF ERRORLEVEL 구문은 "같은 값"을 구하는 구문이 아니기 때문입니다.

1. IF [NOT] ERRORLEVEL 정수 명령어

위와 같은 경우 정수보다 크거나 같으면 뒤따르는 명령어를 실행하게 되어 있습니다.

1. IF ERRORLEVEL 1 command01
2. IF ERRORLEVEL 2 command02
3. IF ERRORLEVEL 3 command03
4. IF ERRORLEVEL 4 command04
5. IF ERRORLEVEL 15 command15

만약에 command01을 실행하고, command02부터는 실행하지 않을 생각이었다면 위와 같은 코드는 작성해서는 안됩니다. 위의 코드는 ERRORLEVEL이 1일 때만 정상 작동하고, 나머지 경우는 항상 사용자가 원하지 않는 작동을 하게 됩니다.

반드시 command01 명령만 실행하겠다면 다음과 같은 두 가지 방법이 있습니다.

1. rem 방법1
2. IF ERRORLEVEL 15 command15
3. IF ERRORLEVEL 4 command04
4. IF ERRORLEVEL 3 command03
5. IF ERRORLEVEL 2 command02
6. IF ERRORLEVEL 1 command05

우선 첫 방법으로는 위와 같이 큰 수부터 비교합니다. 2행에서는 종료코드가 15보다 크거나 같으면 command15 명령을 실행하게 되지요. 그러나 다음 행에 나오는 구문이 실행될 여지는 여전히 남습니다.

그럴 경우 다른 방법으로는 아래와 같이 정확한 수를 비교하게 만듭니다. 2행에서는 종료코드가 15보다 크거나 같고, 16보다 크거나 같지 않으면(작으면), 실행한다는 뜻입니다. 이러한 경우는 종료코드가 정확히 15인 경우뿐입니다.

1. rem 방법2
2. IF ERRORLEVEL 15 IF NOT ERRORLEVEL 16 command15
3. IF ERRORLEVEL 4 IF NOT ERRORLEVEL 5 command04
4. IF ERRORLEVEL 3 IF NOT ERRORLEVEL 4 command03
5. IF ERRORLEVEL 2 IF NOT ERRORLEVEL 3 command02
6. IF ERRORLEVEL 1 IF NOT ERRORLEVEL 2 command05

방법1에서는 goto 명령을 사용할 경우 오류가 생기지 않지만, 일반 명령을 사용할 경우에는 오류가 생길 수 있습니다.

방법2에서는 애초에 정확한 값을 비교하게 되므로 오류가 상당히 줄어들게 됩니다.

이와 비슷한 방법으로는 아래처럼 %ERRORLEVEL%을 쓰는 명령 확장이 있습니다.

1. if /i %ERRORLEVEL% EQU 15 command15

위 문장은 문자열을 비교해 주는 if 구문입니다. 그런데 /i 선택사항이 들어감으로써 융통성을 지니게 되어 일반적인 비교를 하게 됩니다.

1. IF ERRORLEVEL 4 (
2.         echo 파일을 백업하기에는 메모리가 부족하거나
3.         echo 드라이브가 잘못 지정되었거나 명령줄 구문이 틀립니다.
4. ) ELSE IF ERRORLEVEL 2 (
5.         echo 사용자가 CTRL+C를 눌러 백업 작업을 강제 종료했습니다.
6. )

위의 부분은 if 구문에 뒤따르는 명령이 하나가 아닐 때 쓰는 방법입니다. 명령이 하나가 아니라는 말은 같은 명령을 두 번 이상 쓸 경우에도 해당합니다. 위의 문장은 echo 명령을 두 번 썼기 때문에 ( ) (괄호)로 묶어야 합니다. 이러한 구문은 도스의 if와는 호환성이 없는 명령 확장 가운데 하나입니다.

또한 위에서 나타난 else 명령은 반드시 if 문의 끝에만 쓰일 수 있습니다. 또한 else 앞에는 반드시 ) (닫는 괄호)가 와야 합니다. 이때 else의 뜻은 "~이지 않고"라는 뜻이고, 위의 상황에서는 "종료코드가 4보다 크거나 같지 않고"라는 뜻이 됩니다. 뒤따르는 if 구문까지 합해서 해석하면 "종료코드가 4보다 작고, 2보다 크거나 같으면"이라는 뜻이 되지요. 종료코드가 3일 수도 있지만, XCOPY 명령은 종료코드 3을 가지지 않으므로 위의 구문은 정확히 실행됩니다.

또한 위의 방식은 구조적 프로그래밍 또는 절차적 프로그래밍에 근접한 방식입니다. GOTO 명령은 최대한 억제하여 꼭 필요한 경우에만 써야 읽기 좋고, 알아보기 좋고, 고치기 쉬운 코드가 됩니다.

관련 문서

• if 기본 설명

다음 예고

• if exist 구문 및 명령 확장

이 글은 스프링노트에서 작성되었습니다.

들어가며

IF 명령은 FOR 명령과 함께 배치파일에서 지원하는 제어 명령이다. 또한 윈도XP는 도스의 그것보다 훨씬 강력한 기능을 제공하고 있다. 이때 if 명령은 가정문을 만들고, for 명령은 반복문을 만드는 데 쓰인다.

말뜻

IF는 말 그대로 "만약"이라는 뜻을 가지고 있다. 그러므로 이 명령어를 발견하면 영어를 읽듯이 읽어가면 된다.

• 참고 : 프로그래을 짜다 보면 프로그래밍 언어의 어순은 영어의 그것과 아주 비슷함을 알 수 있다. 또한 수학의 수식이 배열되는 순서도 영어의 어순과 많이 닮아 있다.

if 기본 문법

명령줄에서 if 사용

if를 명령줄에서 쓸 수도 있지만, 주로 배치파일 안에서 쓰인다.

위 그림을 보면 분명히 명령줄에서 if 명령을 사용하고 있다. 처음 명령은 현재 디렉터리 아래에 aa 디렉터리가 존재하지 않는다면 Not found를 출력하는 명령이며, 둘째 명령은 c:\2 디렉터리가 존재하면 Found를 출력하는 명령이다.

기본 문법

명령줄에서 다음과 같이 입력하면 기본 사용법을 알 수 있다.

if /?

일단 if 명령은 조건문에서 나타나는 결과에 따라 명령어를 수행하게 됩니다. 이때 조건문은 다음과 같은 세 가지입니다.

• 에러레벨문 : IF [NOT] ERRORLEVEL 숫자 명령어
• 문자열 비교문 : IF [NOT] 문자열1==문자열2 명령어
• 파일 존재 검사문 : IF [NOT] EXIST 파일이름 명령어

if 문은 위 세 가지 경우에 각 조건문이 참값을 가지면 뒤따르는 명령어를 실행시킵니다. 또한 세 가지 모두 "NOT"을 사용하여 조건문이 거짓인 경우에 명령어를 실행시킬 수도 있습니다. if, not, errorlevel, exist 등은 대/소문자를 가립니다. 대문자와 소문자를 구별하지 않으려면 /i 선택사항을 이용하면 됩니다. 다만 이 /i 선택사항은 명령 확장을 이용해야 한다. 다시 말해 도스의 if 명령과 호환성이 없다.

이 기본 문법에서는 명령 확장을 제외한 사항만 다룹니다.

말뜻

• NOT은 영어 뜻 그대로 풀이하면 됩니다. 다시 말해 "~이 아니면"이라고 해석하면 됩니다.
• ERRORLEVEL은 마지막으로 실행된 프로그램이 실행 결과로서 사용자에게 반환하는 마침 코드를 가리킵니다. 흔히 반환값이라고 부르며, 0부터 255 사이의 값을 가집니다. 일반적으로 "error level"이라고 띄어 쓰지만, 배치파일에서는 "errorlevel"이라고 자주 붙여 씁니다. 또한 ERRORLEVEL과 %ERRORLEVEL%은 서로 다르므로 주의해야 합니다. 마침코드가 뒤따르는 수보다 크거나 같으면 조건을 참으로 지정합니다.
• 문자열은 "문자의 배열"이라는 뜻입니다. 쉽게 말하자면 화면에 보이는 글자의 모임 또는 묶음이거나, 기억장치에 저장된 문자의 모임 또는 묶음입니다. 명령줄에서 문자열은 <Enter>가 입력될 때까지 명령줄에 나타난 문자의 모임입니다. 또한 환경변수에 저장된 값은 기본적으로 문자열입니다. 이렇듯이 가리키는 대상에 따라 문자열은 조금씩 다르지만, 문자의 모임 또는 문자의 묶음이라는 점에서는 항상 같습니다.
• 문자열의 비교 : 문자열을 비교할 때는 등호를 두 번 써서 비교합니다. 다시 말해 "문자열1==문자열2"와 같은 꼴로 비교하게 됩니다.
• EXIST는 "존재한다"라는 뜻입니다. 이것은 항상 뒤따르는 파일이나 디렉터리가 존재하는지를 묻고, 존재하면 조건을 참으로 지정합니다.
• ELSE는 "~이 아니면"이라는 뜻입니다. 이것은 앞서 나온 IF 명령이 조건을 거짓으로 지정할 경우에 실행하게 됩니다. IF 기본 명령에서는 다루지 않습니다.

예제

ERRORLEVEL문

마침 코드를 검사하여 알맞은 문장을 보여줍니다.

1. @echo off
2. rem 파일명 : GBackup1H2P.cmd
3. rem 지은이 : koc2000/SALM
4. rem 저작권 : GPL v3
5.  
6. rem 예제 11-1.
7. rem 고스트 작업이 정상적으로 끝났는지를 알려준다.
8.  
9. rem 첫 번째 하드디스크 첫 번째 파티션에서
10. rem 첫 번째 하드디스크 두 번째 파티션으로 백업한다.
11. GHOST.exe -CLONE,MODE=PDUMP,SRC=1:1,DST=1:2\GHOST.GHO -Z9 -AUTO -SURE -RB
12.  
13. REM ERRORLEVEL 값이 1보다 작으면 NOERROR로 이동한다.
14. IF NOT ERRORLEVEL 1 GOTO NOERROR
15.     ECHO ##############################################
16.     ECHO ##      백업 도중 오류가 발생했습니다.      ##
17.     ECHO ##############################################
18.     GOTO END
19.  
20. :NOERROR
21.     ECHO ##############################################
22.     ECHO ##    백업 작업을 정상적으로 마쳤습니다.    ##
23.     ECHO ##############################################
24.  
25. :END
26. REM 배치파일을 종료할 때 마침 코드를 되돌려준다.
27. REM 이때 %ERRORLEVEL% 환경변수는 일종의 SET 명령 확장에 해당한다.
28. EXIT /B %ERRORLEVEL%

시만텍 사의 프로그램은 오류가 발생하지 않으면 마침 코드로 0을 돌려주고, 오류가 발생하면 1 또는 1보다 큰 값을 돌려준다. 그것을 이용하여 고스트가 제대로 작업을 마쳤는지를 사용자에게 알려줄 수 있다.

• 참고 : 위 GBackup1H2P.cmd 배치파일은 실패작이다. 배치파일을 실행할 환경을 고려하지 않고 작성한 탓에 도스에서도 윈도에서도 디스크를 백업한다는 본래 목적대로 실행이 되지 않는다. 물론 ERRORLEVEL문을 시험하는 예제라는 의미에서는 잘 작동한다.

문자열 비교문

if 명령을 이용하여 문자열을 비교할 수 있다. 도스에서는 문자열에 공백이 들어가는 경우가 없으나, 윈도에서는 공백이 들어갈 수도 있다.

앞서 만든 HelloWho2.cmd 파일을 참조하여 매개변수를 출력하는 배치파일을 만들었다.

1. @ECHO OFF
2. REM 파일명 : ViewPara.bat
3. REM 지은이 : koc2000/SALM
4. REM 저작권 : GPL v3
5.  
6. REM 예제 11-2.
7. REM 매개변수를 한 줄에 하나씩 보여준다.
8.  
9. REM 가장 먼저 %0을 보여준다.
10. ECHO %0
11.  
12. REM for 명령을 쓰지 않고 순환문을 만든다.
13. :LOOP_START
14.     REM %1 매개변수가 없으면 순환문을 끝낸다.
15.     IF * == %1* GOTO :LOOP_END
16.  
17.     REM %1 매개변수를 출력한다.
18.     ECHO %1
19.  
20.     REM %(N) 매개변수를 %(N-1) 매개변수로 자리 이동한다.
21.     SHIFT
22.  
23.     GOTO :LOOP_START
24. :LOOP_END
25.  
26. :END

GOTO 명령은 배치파일 내부에서 레이블이 있는 곳으로 CMD.EXE 명령줄을 옮기는 역할을 한다. 레이블은 앞에 콜론( : )을 붙여 구분하고 있다.

또한 SHIFT 명령은 %0부터 %9까지의 매개변수의 순서를 바꾸어 주는 역할을 한다. 다시 말해 %9는 %8이 되고, %8은 %7이 된다. 그렇게 하나씩 이동하며 %1은 %0이 된다. 또한 %9 바깥에 있던, 지금까지 표현하지 못했던, %10의 위치에 있던 값을 %9로 옮겨 준다.

ViewPara.bat 배치 파일은 윈도와 도스에서 모두 실행할 수 있으나, 실행 결과는 항상 같지 않다.

위는 윈도XP의 명령 프롬프트이며, 아래는 버추얼박스에서 도스 v6.22를 실행한 화면이다. 다른 경우는 모두 같지만, 따옴표로 묶인 부분을 처리하는 방법이 다르다. 다시 말해 윈도XP에서는 따옴표로 묶인 부분은 하나의 문자열로 보았지만, 도스에서는 따옴표는 무시하고 화이트스페이스(공백문자)로 나뉜 부분을 문자열로 보았다.

또한 이 문자열 비교문은 운영체제의 환경변수를 비교할 때도 쓸 수 있다.

파일 존재 검사문

배치파일은 작업에 앞서 파일이나 디렉터리가 존재하는지를 알아볼 수 있는 방법을 제공한다. 바로 "if exist"라는 구문이다.

1. @ECHO OFF
2. REM 파일명 : FindFile.cmd
3. REM 지은이 : koc2000/SALM
4. REM 저작권 : GPL v3
5.  
6. REM 예제 11-3.
7. REM 명령줄에서 지정한 파일이 현재 경로에 있는지를 알려준다.
8.  
9. REM 판별 : %1이 없으면 도움말을 보여준다.
10. IF * == %1* GOTO :ViewHelp
11.  
12. REM 판별 : %1이 있으면 그 파일이 있는지를 보여준다.
13. IF EXIST %1 GOTO :Found
14. ECHO File %1 was Not Found.
15. ECHO.
16. GOTO :END
17.  
18. :Found
19. ECHO File %1 was Found.
20. ECHO.
21. GOTO :END
22.  
23. REM 도움말
24. :ViewHelp
25. ECHO FindFile v0.0.1
26. ECHO Syntax : FindFile FileName
27. ECHO.
28.  
29. :END

명령줄에서 매개변수로 파일명을 입력받아, 그 파일명에 해당하는 파일이 존재하는지를 알려준다.

다음 예고

IF 명령을 하나씩 짚어보자. (1)

이 글은 스프링노트에서 작성되었습니다.

들어가기에 앞서 자꾸 예고에 없는 내용이 끼어들어 죄송하다는 말을 먼저 하겠다.

들어가며

매개변수가 배치파일에 전달되는 모습을 그림으로 알아보는 자리를 마련했습니다. 뭐든 그림이 더 알기 쉽다고 생각하기 때문입니다.

말뜻

매개변수(parameter)는 도스와 윈도의 명령줄에서 어떤 명령어와 관계를 맺고 어떤 작용을 지시하는 변수나 인자를 가리킨다고 했습니다. 그런데 좀 더 보편적으로 설명한다면 운영체제와 명령어가 관ㄹ계를 가지고 있는데, 이때 명령어에 어떤 작용을 지시하는 변수를 매개변수라고 부릅니다.

매개변수와 응용프로그램

매개변수는 명령줄에서 입력받는 값이 된다. 이때 도스와 윈도에서 첫번째 매개변수를 %0이라 부르며, 이것은 운영체제에서 처리하게 된다. 다시 말해 %0을 처리하여 이것을 실행할 수 있는지, 실행할 수 없으면 그 파일과 연결된 프로그램을 호출하여 처리합니다. 다시 말해 명령 프롬프트에서 문서 파일 이름을 입력하고 <Enter>를 입력하면 바로 그 문서와 연결된 문서 편집기를 호출하여 실행시켜 준다.

우선 목록은 다음과 같다.

이때 명령줄에서 exam.txt 라고 입력하면 저 파일에 맞는 프로그램을 호출하면서 %0 매개변수로 입력 받은 exam.txt 파일을 읽어온다.

위와 같이 파일이 연결된 프로그램을 가지고 있다면 바로 읽어올 수 있다. 이것은 .txt 파일에 대한 정보를 윈도XP가 레지스트리에 가지고 있기 때문에 가능한 일이다.

이것은 다음과 같이 나타낼 수 있다.

명령줄에 입력된 매개변수는 %0과 %*로 나뉜다. 이때 매개변수 %1부터는 윈도에서 직접 구분하여 매개변수 %0으로 넘겨주는 때도 있고, 그게 아니면 %*과 같은 문자열의 형태로 넘겨줄 수도 있다.

위와 같이 윈도에서 %0 매개변수에 해당하는 ExecFile.exe를 불러들여 실행하면서 %1 매개변수부터는 문자열의 형태 또는 이미 분류된 형태로 %0 매개변수로 넘겨줘서 처리하라고 시키게 된다.

배치파일의 경우는 배치파일 안에 명령어가 하나일 때와 여럿일 때로 구분하여 생각할 수 있다.

위와 같이 배치파일 내부에서 입력 받은 매개변수를 모두 이용할 수도 있고, 그게 아니라 매개 변수 가운데 일부만을 이용할 수도 있다. 그것은 배치파일 제작자가 하기 나름이다. 일부러 더미 변수(쓰레기값)를 입력 받게 할 수도 있다.

배치파일 내부에서 사용한 명령어가 여럿이라면 위와 같이 복잡한 구성을 지닐 수도 있다. 그러나 대개는 %1, %2, %3, %4, %5, %6, %7, %8, %9, %*과 같은 매개변수는 배치파일 첫머리에서 해석하여 프로그래머가 지정한 환경변수로 치환하여 저장하는 것이 일반적이며, 위와 같은 형태는 예시를 들기 위해 나타낸 상황일 뿐임에 유의하자.

실제로 위와 같이 프로그램을 작성했다면, 그다지 좋은 프로그래밍 습관이 아니라고 해야겠다.

과제

지난 시간에 냈던 과제의 결과는 다음과 같다.

• ECHO 명령을 이용하여 화면에 OFF라는 세 글자를 출력하시오. 

1. @ECHO.OFF

위의 코드는 아래와 같은 결과를 보인다. 위의 코드에서 ECHO와 OFF 사이에 빨간 점(.)을 잘 보자.

OFF

다음 코드는 OFF 앞에 공백을 한 칸 추가할 수 있다. 공백에는 색깔을 넣었다.

1. @ECHO. OFF

다음 코드는 OFF 앞에 공백을 두 칸 추가할 수 있다. 공백에는 서로 다른 색깔을 넣었다.

1. @ECHO.  OFF

다음 코드는 OFF 앞에 공백을 두 칸 추가한 것과 같은 효과를 줄 수 있다. <Alt+255>는 아스키문자 255번을 가리킨다. 위의 코드들과는 달리 빨간 점(.)이 없다.

1. @ECHO <Alt+255>OFF

• DIR 명령을 이용하여 원하는 폴더(디렉터리)의 내용을 폴더(디렉터리)만 보여주도록 한다. /A /P 선택사항을 반드시 사용할 것.

1. DIR /A:D /P %1
2. DIR /AD /P %1

위의 두 코드 가운데 하나가 자신의 배치 파일에 있고, 그것이 실제로 작동하면 정답이다.

다음 예고

if 명령 이해하기.

이 글은 스프링노트에서 작성되었습니다.

들어가며

앞서 매개변수의 의미와 자기자신(?)을 출력하는 배치파일을 소개했다.

이 글에서는 매개변수를 활용하여 프로그램을 작성해 보자.

말뜻

매개변수, 곧 파라미터(parameter)는 도스와 윈도의 명령줄에서 어떤 명령어와 관계를 맺고 어떤 작용을 지시하는 변수나 인자를 가리킨다. 자주 언급되었던 ECHO OFF 명령에서 실제 명령어는 ECHO뿐이고, OFF는 매개 변수이다. 명령줄에서 명령어 뒤에 죽 나열하는 문자열은 대개 매개변수이다.

또한 매개변수 전달이란 명령줄에 입력한 명령과 매개변수를 프로그램에서 사용할 수 있는 형태로 알려주는 일을 가리킨다. 이를 위해 배치파일은 %n의 꼴을 사용한다.

1. @echo Hello %0!

앞서 사용했던 저 한 줄짜리 코드 마지막에 붙은 %0와 같은 꼴로 쓰인다는 뜻이다.

매개변수를 정확히 알기

매개변수 %0과 %*

지금까지 말한 매개변수는 정확하지 않다. 물론 그와 같은 설명이 틀렸다는 말이 아니다. 그러나 엄밀히 말하면 옳지는 않다.

1. @rem HelloWho.cmd
2. @echo Hello %0, %*!

첫줄은 주석이므로 적든지 말든지 알아서 하기 바란다. 둘째 줄이 실제 실행 코드이다.

아무튼 아래 그림을 보고 여러 가지로 적용해 보기 바란다.

위의 그림을 보면 매개변수 %0은 배치파일 자신이 아님을 알 수 있다. 만약 매개변수 %0으로 자신을 가리키게 했다면 매번 다른 결과가 나오지 않아야 하기 때문이다. 다른 의미로 매개변수 %0은 명령줄에 입력된 첫번째 인자를 가리킨다는 뜻이다. 컴퓨터에서 첫번째 인자를 0번으로 표기하는 일이 잦으므로 그다지 놀라운 일은 아니다.

또한 위의 코드에서 %0과 %*를 나누어 썼다는 점에서 한 가지를 알 수 있다. %0은 일반적인 매개변수와는 다르게 취급된다는 점이다. %*는 "명령줄에 입력된 모든 매개변수"라는 뜻임에도 불구하고 %0을 제외하고 있음에서 그것을 알 수 있다.

다른 매개변수

매개변수는 앞서 말했듯이 %n의 꼴로 나타낸다. 이때 n은 일반적으로 숫자이고, 특별한 경우에 *(별표)가 올 수 있다. 이 말은 곧 %10과 같은 매개변수는 존재하지 않는다는 뜻이다. 숫자와 수를 구별하자. 10은 수이지만, 숫자는 아니다. 그에 따라 %n의 꼴로 나타낼 수 있는 매개변수는 %0, %1, %2, %3, %4, %5, %6, %7, %8, %9, %*, 이렇게 열한 개이다.

하지만 위에서는 분명히 "%10"에 해당하는 매개변수를 전달 받았다. 물론 그것은 사실이다. 다만 %10과 같은 매개변수가 존재하지 않을 뿐이고, 명령줄에서 입력받는 매개변수는 컴퓨터의 기억장치 어딘가에 저장되어 있다는 뜻이다. %*는 자신이 가진 특별한 기능, 곧 %0을 제외한 모든 매개변수를 불러오는 기능을 사용해서 처리했을 뿐이다.

1. @rem HelloWho2.cmd
2. @echo Hello %0, %*!
   @echo Hello %0, %1 %2 %3 %4 %5 %6 %7 %8 %9!

두 코드의 차이를 보이기 위해 한꺼번에 작성했다.

다른 매개변수를 넣어서 시험해 보기 바란다.

%* 정확히 알기

아까 알려주고는 뭘 또 정확히 알자고 그러냐고? 아까 그것은 %0과 함께 알려준 내용이고, %*은 다른 매개변수와는 조금 다른 점이 있다는 말씀!

%*을 편의상 별 매개변수라고 부르자.

이 별 매개변수는 매개변수 자체를 다루지 않는다. 헉! 무슨 헛소리를 하느냐고? 정말이다. 이 별 매개변수 녀석이 다루는 것은 명령줄 자체이다.

윗줄은 분명히 별 매개변수를 이용하여 출력하였고, 아랫줄은 %n의 꼴로 출력하였다. 별 매개변수가 명령줄을 다룬다는 뜻은 위와 같이 매개변수 사이에 있는 공백까지 문자(공백문자)로 인식하여 전달 받았음을 뜻한다. 반면에 %1, %2 등은 공백문자로 나뉜 각각의 매개변수를 전달 받아 이용하고 있다.

매개변수 활용

예제 5에서 윈도 폴더를 보여주는 배치파일을 만들었다. 그것을 고쳐서 사용자가 지정하는 폴더(엄밀히 말하면 디렉터리)를 보여주는 배치파일을 만들자.

D:\Usr\LCP\바탕 화면\배치파일>dir /?
디렉터리에 있는 파일과 하위 디렉터리 목록을 보여줍니다.

DIR [드라이브:][경로][파일 이름] [/A[[:]특성]] [/B] [/C] [/D] [/L] [/N]
  [/O[[:]정렬 순서]] [/P] [/Q] [/S] [/T[[:]시간 필드]] [/W] [/X] [/4]

  [드라이브:][경로][파일 이름]
              나타낼 드라이브, 디렉터리 및/또는 파일을 지정합니다.

  /A          지정된 특성을 가진 파일을 보여줍니다.
  특성        D  디렉터리                   R  읽기 전용 파일
              H  숨김 파일                  A  기록 파일
              S  시스템 파일                -  부정을 뜻하는 접두사
  /B          최소 형식을 사용합니다 (머리말 정보나 요약 없음).
  /C          파일 크기에 1000단위로 분리 기호를 보여줍니다. 이것은 기본값
              입니다. 분리 기호를 표시하지 않으려면 /-C를 사용하십시오.
  /D          /W와 같으나 세로로 배열하여 보여줍니다.
  /L          소문자를 사용합니다.
  /N          파일 이름이 제일 오른쪽에 오도록 새로운 긴 목록 형식을
              사용합니다.
  /O          파일을 정렬된 순서로 보여줍니다.
  정렬순서    N  이름순(문자 순서)    S  크기순(작은 것 먼저)
              E  확장명순(문자 순서)  D  날짜/시간순(가장 이전 것 먼저)
              G  그룹 디렉터리 먼저         -  순서를 반대로 하는 접두 기호
  /P          정보가 한 화면에 꽉 차면 잠깐 멈춥니다.
  /Q          파일 소유자를 보여 줍니다.
  /S          지정한 디렉터리와 하위 디렉터리를 포함하여 보여줍니다.
  /T          정렬에 사용할 시간 필드를 지정합니다.
  시간필드   C  작성한 시간
              A  마지막 액세스한 시간
              W  마지막 기록한 시간
  /W          이름만 가로로 배열하여 보여줍니다.
  /X          8.3 파일 이름이 아닌 파일에 대한 짧은 이름을 보여줍니다.
              이 형식은 긴 이름 앞에 짧은 이름이 추가된 것으로 /N 형식과
              같습니다. 짧은 이름이 없으면 공백을 보여줍니다.
  /4          4자리수 연도를 표시합니다.

스위치를 DIRCMD 환경 변수로 미리 설정할 수 있습니다. 하이픈(-)을
스위치 앞에 접두 기호로 주면 미리 설정된 스위치에 우선합니다. (예, /-W)


D:\Usr\LCP\바탕 화면\배치파일>

우선 명령줄에서 dir /? 라고 명령을 주면 위와 같은 내용을 보여준다. "/문자"의 꼴로 나타나는 것이 매개변수 가운데 선택사항(옵션)이다.

이 가운데 우리가 사용할 선택사항은 /a /p /4 이다. 더 추가하고 싶으면 스스로 선택하기 바란다. 셸 내장 명령어는 선택사항을 줄 때 대부분 대문자/소문자를 가리지 않는다. 그래서 앞의 세 선택사항은 /A /P /4 와 같은 의미이다.

1. @echo off
2. rem 예제 10 : 사용자가 지정하는 폴더를 보여주는 배치파일
3. rem 파일명 : exam10.cmd
4. rem 지은이 : koc2000/SALM
5. rem 저작권 : GPL v3
6. echo 예제 10.
7. echo 사용자가 지정하는 폴더를 보여준다.
8. echo 보다가 종료하려면 Ctrl+Pause 키나 Ctrl+C를 누르시오.
9. PAUSE
10. echo.
11. DIR /A /P /4 %1

맨 마지막 줄이 이 배치파일의 핵심이다. 사실 저 한 줄만 있어도 실행에는 전혀 지장이 없다. 저대로 실행해 보고 나서 의문이 생긴다면 글 남기세요.

과제

다들 싫겠지만, 약간의 과제를 내겠다.

• ECHO 명령을 이용하여 화면에 OFF라는 세 글자를 출력하시오. 예시 화면은 다음과 같다.

OFF의 위치나 대/소문자 등은 자신이 좋아하는 위치와 형태를 따르면 된다. 위와 같이 세 번 나타낼 필요는 없다. 1회만 출력하면 된다. 저것을 입력하기 위해 배치파일에 Echo off 라고 하면 아무것도 출력되지 않는다. 어떻게 해야 출력할 수 있는지는 스스로 탐구해야 한다. 이 문제도 알고 나면 너무 쉽다. 다만 O F F 처럼 띄어쓰기를 하면 안 된다.

• DIR 명령을 이용하여 원하는 폴더(디렉터리)의 내용을 폴더(디렉터리)만 보여주도록 한다. /A /P 선택사항을 반드시 사용할 것. 예시 화면은 다음과 같다.

다음 예고

IF 이용하기

이 글은 스프링노트에서 작성되었습니다.

들어가며

배치파일에서 프로그램을 실행할 때 경우에 따라서는 잠시 멈추거나, 때에 따라서 완전히 종료해야 할 수도 있다.

그러한 경우는 주로 배치파일의 일부에서 오동작이 생겨서 배치파일 전체에 영향을 주는 때나 진행 화면을 잠시 멈춘 뒤 보고 싶을 경우 등이 이에 해당한다.

잠시 멈추기

키를 눌러 잠시 멈추기

윈도 폴더를 보여주는 배치파일을 만들어 보자.

1. @echo off
2. rem 예제 5 : 윈도 폴더를 보여주는 배치파일
3. rem 파일명 : exam05.bat
4. rem 지은이 : koc2000/SALM
5. rem 저작권 : GPL v3
6.  
7. echo 예제 5.
8. echo 윈도 폴더를 보여준다.
9. echo 보다가 잠시 멈추려면 Pause 키나 Ctrl+S를 누르시오.
10. echo.
11. dir C:\WINDOWS /s /a
12. echo 끝.

배치파일을 만들 때에는 안내문을 보여줄 수 있게 하려고 했는데, 뭔가가 번개같이 지나가 버려 전혀 알아볼 수가 없었다. 본의 아니게 번갯불에 콩 볶는 모습을 보여준 격이 되었다.

<예제5 결과 화면>

이번에는 명령 프롬프트에서 exam05 라고 명령을 내린 뒤에 얼른 <Pause> 키를 누르도록 하자. <Pause> 키는 키보드의 왼쪽 위, 숫자 패드의 왼쪽 위에 있다.

<예제5 잠시 멈춘 화면>

이때 <Pause> 키는 잠시 멈추라는 기능을 가지고 있다. 물론 윈도에서는 거의 동작하지 않지만, 이렇듯이 명령 프롬프트나 도스 상태에서 잘 작동한다. 도스 상태에서도 게임 등에서는 마찬가지로 거의 동작하지 않는다.

멈춤 명령

물론 도스에서도 명령행에서 멈추게 하는 명령어가 있다.

1. @echo off
2. rem 예제 5-1 : 윈도 폴더를 보여주는 배치파일
3. rem 파일명 : exam05-1.bat
4. rem 지은이 : koc2000/SALM
5. rem 저작권 : GPL v3
6.  
7. echo 예제 5-1.
8. echo 윈도 폴더를 보여준다.
9. echo 보다가 잠시 멈추려면 Pause 키나 Ctrl+S를 누르시오.
10. echo 다시 재개하려면 아무 키나 누르십시오.
11. echo.
12. echo 윈도 폴더를 보여줍니다.
13. pause
14. echo.
15. dir C:\WINDOWS /s /a
16. echo 끝.

위에 추가된 PAUSE 명령이 그것이다.

위의 명령을 실행시키면 아래처럼 일단 한 번 멈춘다.

<예제5-1 잠시 멈춘 화면>

강제 중단

방금 만든 exam06.cmd 파일을 다음과 입력하여 저장하자.

1. @echo off
2. rem 예제 6 : 시간과 날짜를 보여주는 도중에 잠시 멈추고
3. rem          강제 종료에 대해 알려준다.
4. rem 파일명 : exam06.cmd
5. rem 지은이 : koc2000/SALM
6. rem 저작권 : GPL v3
7.  
8. echo 예제 6.
9. echo 날짜를 보여주고 멈춥니다.
10. echo.
11. echo 날짜를 바꾸려면 알맞은 날짜를 형식에 맞추어 넣으시오.
12. echo 날짜를 바꾸지 않으려면 Enter를 누르시오.
13. echo.
14. date
15. echo.
16. echo 시간을 보여주고 멈춥니다.
17. echo 종료하려면 Ctrl+C 또는 Ctrl+Break를 누르시오.
18. pause
19. echo.
20. echo 시간을 바꾸려면 알맞은 시간을 형식에 맞추어 넣으시오.
21. echo 시간을 바꾸지 않으려면 Enter를 누르시오.
22. echo.
23. time
24. echo.
25. echo 끝.

줄 수는 많지만, 실제 코드는 얼마 되지 않는다. 굳이 실행 화면은 보이지 않겠다. 실제로 실행해 보면 몇 가지 의문이 생길 터이다. 그때 질문을 올리기를 바란다. 위에서 보이고자 하는 바는 명령줄에서 <Ctrl+C> 또는 <Ctrl+Break>를 누르면 강제 중단하는 기능이 있다는 데 있다.

매개 변수

이번에는 지난 번에 예고했던 "파라미터"를 배치파일에 전달하는 방법에 대해서는 다루지 않겠다. 차례로 보면 그것을 알려줘야 하지만, 그것이 무엇인지만 설명하고 넘어가겠다.

파 라미터(parameter)는 도스와 윈도에서 매개 변수로 불린다. 이것은 명령줄에서 어떤 명령어와 관계를 맺고 어떤 작용을 지시하는 변수나 인자를 가리킨다. 자주 언급되었던 ECHO OFF 명령에서 실제 명령어는 ECHO뿐이고, OFF는 매개 변수이다.

1. cls
2. echo Hello World!
3. pause

맨 처음 소개했던 clear.bat 파일의 내용이다.

위에서 CLS, ECHO, PAUSE는 명령어이고, ECHO 다음에 오는 Hello World! 부분은 매개 변수이다. 이때 명령어 자신도 매개 변수에 포함된다. 이것은 아주 특별한 경우이다.

1. @echo Hello World!

위와 같이 입력하고 Hello.cmd 라고 저장하자. 단 한 줄이지만, 엄연히 배치파일이며, 프로그램이다. (색깔은 구분하기 위해 넣은 것이다. 내용만 제대로 입력하면 된다.)

실행시켜 보면 다음과 같이 나온다.

이대 내용을 약간 바꾸어 HelloMe.cmd 라고 저장하자. 끝에 %0 은 퍼센트 기호와 숫자 0 (영)이다.

1. @echo Hello %0!

실행 결과는 직접 보고 느끼기 바란다. 그것까지 알려주면 식상할 듯 여겨져 올리지 않았다.

배치파일 이름을 바꾸어서 실행해 보기 바란다. 뒤에 확장자를 붙여 실행해 보고, 붙이지 않고 실행해 보기 바란다.

이때 명령어 자신도 매개 변수에 포함된다. 이것은 아주 특별한 경우이다.

저 말이 무슨 뜻인지 확실히 알게 되리라 생각한다.

아무튼 매개변수를 배치파일에 전달하라고 지정한 적은 없다. 그러나 명령어 해석기 안에는 이미 명령어 자신을 매개변수로 인식하도록 프로그램되어 있다는 점을 기억하자.

요약

• 명령줄에서 잠시 멈출 때는 <Ctrl+S> 또는 <Break> 키를 누르면 된다.
• 명령줄에서 강제 종료할 때는 <Ctrl+C> 또는 <Ctrl+Break> 키를 누르면 된다.

• 파라미터(parameter)는 도스와 윈도에서 매개 변수로 불린다. 이것은 명령줄에서 어떤 명령어와 관계를 맺고 어떤 작용을 지시하는 변수나 인자를 가리킨다.

  • 명령어 자신도 매개변수이다.

지금까지 만들었던 배치파일을 압축하여 묶었다. 몇몇 파일은 강좌에서는 없었던 것도 있지만 시험 삼아 만든 파일이다.

• 파일 : batch001.zip (3,877 바이트)
  
• CRC32 값 : C1D834F1
  
• MD5 값 : 7758c952ca718a16c65bb31793d10841

다음 예고

이번에는 지난 번에 예고했던 매개 변수를 배치파일에 전달하는 방법에 대해서는 좀 더 나중에 다루겠다.

일단 다음 강좌에서는 쉬어가는 시간을 마련했다. 기초가 끝났으므로 이것저것 잡다한 이야기를 하겠다.

이 글은 스프링노트에서 작성되었습니다.

들어가며

배치파일에서 좀 더 자세한 화면 출력과 배치파일의 가독성에 대해 알아보자.

화면 출력에서는 빈 줄과 ECHO와는 관계를 알게 되며, 배치파일의 가독성에서는 프로그래밍 일반에서 다루는 보기 좋은 코딩에 대해서 알게 됨을 목표로 하고 있다.

빈 줄 출력

배치파일에서 빈줄을 출력하는 일은 상당히 쉬우면서도 상당히 어렵다. 알기만 하면 아주 간단하지만, 모를 때는 갑갑하게 만드는 것이 "빈 줄 출력"이다.

첫 번째 시도

실험적인 코드를 만들어 보자.

• 소스 코드 : 예제 4
  @echo off
  rem 예제 4 : 빈 줄 출력 예제
  rem 파일명 : exam04.bat
  rem 지은이 : koc2000/SALM
  rem 저작권 : GPL v3
  
  echo 예제 4.
  
  echo 이것은 빈 줄 출력 예제 4입니다.
  
  echo 끝.

메모장을 열어서 위와 같은 코드를 입력하고 실행시켜 보기 바란다. 엔터를 쳐서 빈줄을 만든 만큼 빈 줄이 화면에 출력되는가?

<예제4 출력화면>

사실 이것은 그리 놀라운 일이 아니다.

지난 글에서 말한 ECHO 명령의 역할이 무엇인지를 생각하면 당연한 결과이다. ECHO OFF 는 "사용자에게 보이는 명령어 반향을 끈다"라는 뜻이었다. <Enter>를 쳐서 빈 줄을 만든 경우 사용자에게 보이는 명령어 반향이 공백 1줄(빈 줄)이었는데, 그 명령어 반향을 감추게 되면, <Enter>로써 만든 빈 줄이 사라지는 효과가 생긴다. 그렇다고 ECHO ON 을 하여 명령어 반향을 켜서 지난번의 그 지저분한 화면을 보기도 조금 그렇다. 빈대 잡으려고 초가 삼간을 태우는 격이다.

앞서 말했듯이 배치파일에서 빈 줄을 출력하는 일은 상당히 쉬우면서도 상당히 어렵다.

또 다른 시도

방금 만든 exam04.bat 파일을 다음과 같이 편집하고 exam04-1.bat라는 이름으로 저장하자.

• 소스 코드 : 예제 4
  rem 예제 4-1 : 화면에 간단한 말을 출력한다.
  rem 파일명 : exam04-1.bat
  rem 지은이 : koc2000/SALM
  rem 저작권 : GPL v3
  echo 예제 4-1.
  echo _
  echo 이 프로그램은 화면 출력 예제 4-1입니다.
  echo _
  echo 끝.

실행해 보면, 아까와는 다른 결과가 나왔음을 알 수 있다. 위에서 주황색 바탕의 밑줄은 밑줄을 입력하라는 말이 아니라 스페이스 바를 한 번 눌러 빈칸을 만들라는 뜻이다. 빈칸은 하나가 아니라 훨씬 많아도 상관없다.

<예제4-1 출력화면>

이때 알 수 있는 것은 빈칸의 수가 아무리 많아도 같은 결과가 나온다는 점이다.

그렇다면 빈칸이라도 출력이 되어야 옳지 않을까?

이렇게 묻는 사람이 있다면 이렇게 답해 주겠다.

방금 말했다. 빈칸의 수가 아무리 많아도 같은 결과가 나온다.

이 말은 명령어 다음에 빈칸이 하나이든 백이든, 아니면 빈칸이 없든 같은 결과가 나온다는 뜻이다. 즉 ECHO 다음에, 다른 옵션이 없다면, 빈칸이 있든 없든 같은 의미를 가지게 된다는 말이다.

ECHO 명령의 기능은 (1) 메시지를 보여주거나 (2) 명령어 반향을 켜거나 끄고(기본값은 켠다), (3) ECHO 명령만 입력했을 때 반향 설정값을 보여준다. 이렇게 세 가지였다. 이 가운데 (3)번에 해당한다.

결국 ECHO 뒤에 빈칸을 넣어서 빈 줄을 입력하게 하는 방법도 실패다.

고전적인 방법

1980년대나 1990년대 초에 나온 컴퓨터 서적에서는 대개 아스키문자 255번을 이용하라고 하고 있다. 물론 나는 이 방법을 배우지는 않았다. 내가 컴퓨터 학원에 다닐 때는 좀 더 간단한 방법을 배웠기 때문이다.

고작 1백 년도 되지 않은 컴퓨터 역사에서 "고전"이 있을까마는 따지지 말자. "좀 더 오래된"이라는 의미를 부여하기 위해 쓴 말일 뿐이다.

우선 이 작업을 위해서는 exam04-1.bat 파일을 복사하여 exam04-2.bat 파일을 만든다. (복사 방법과 이름 바꾸는 방법은 모두 알고 있으리라 생각하고 생략하겠다. 모르면 댓글 남기기 바란다.)

명령 프롬프트에서 다음과 같이 입력한다.

edit exam04-2.bat

음, 뭔가 달라져 보이지 않는가?

<도스 에디터 화면>

그 자리에서 <Alt>를 누른 상태에서 오른쪽 숫자판에서 2, 5, 5를 차례대로 누른 다음 키보드에서 손을 떼며 화면을 잘 살피기 바란다. (방금 했던 작업은 키보드를 이용하여 아스키문자 255번을 입력하는 작업이다.)

<도스 에디터 화면 : 255번 문자 입력 화면>

아래쪽으로 옮겨서 방금 그 작업을 다시 하자. 이때 주의할 점은 반드시 ECHO 뒤에 한 칸 공백을 둔 뒤에 아스키문자 255번을 입력해야 한다.

작업을 마쳤으면 저장하자. <Alt>를 한 번 누르면 왼쪽 상단의 [F/파일] 부분이 검게 바뀐다. 그 화면에서 F, S를 누른다. 다시 말해, <Alt>를 눌렀다 손을 떼고, F를 눌렀다가 손을 떼고, S를 눌렀다가 손을 떼면 저장이 된다.

저장도 마쳤으니 종료하자. 종료는 <Alt>, F, X 이다.

도스 상태에서 실행시켜 보자. 기대해도 좋다.

<예제4-2 출력화면>

드디어 성공했다.

그러나 아스키문자 255번을 누르기 위해서 해야 할 일이 너무 많고 번거롭다. 물론 아크로에디트를 비롯한 많은 문서 편집기가 "아스키코드"(아스키문자) 값을 지원해 주지만, 모르는 사람도 많다. 특히 윈도의 기본 문서 편집기인 메모장에서는 아스키문자 255번을 입력할 수 없다.

좀 더 새로운 방법

아스키문자 255번을 입력하여 빈줄을 나타내는 방법은 너무 번거로웠다. 그렇게 해서 알려진 방법이 바로 문서화되지 않은 방법이다. (MS 제품과 관련한 팁에는 많은 "문서화되지 않은" 방법이 존재한다. 심지어 일부 팁은 마이크로소프트 홈페이지에서도 활용하고 있다. 그러나 어디까지나 "문서화되지 않은" 방법은 해당 버전에서만 유효하며, 다음 버전에서는 언제라도 사라질 수 있음을 기억하자.)

exam04-1.bat 파일을 복사하여 exam04-3.bat 파일을 만든다.

1. @echo off
   rem 예제 4-3 : 화면에 간단한 말을 출력한다.
   rem 파일명 : exam04-3.bat
   rem 지은이 : koc2000/SALM
   rem 저작권 : GPL v3
   echo 예제 4-3.
   echo.
   echo 이 프로그램은 화면 출력 예제 4-3입니다.
   echo.
   echo 끝.

빨간 색으로 표시된 점( . )이 추가된 부분이다. 그 부분을 잘 보기 바란다.

실행하면 다음과 같다.

<예제4-3 출력화면>

1. echo.

저 코드가 "빈 줄"을 출력하는 코드인 셈이다. 특이하게 ECHO 명령에 붙여서 써야 한다. 띄어쓰기를 하면? 직접 해보기를 바란다.

아주 간단하면서 쉬운 방법이다. 모를 때는 갑갑하게 만든 빈 줄 출력이지만, 알게 되면 어이 없을 정도로 쉽다. (물론 세상사가 대부분 그렇다. 오죽하면 "콜롬버스의 달걀"이라는 말이 생겼을까? 당시 "그냥 서쪽으로 가기만 하면 되는 쉬운 일이다."라고 주장하면서 콜럼버스의 업적을 폄하하는 사람들이 생겨나자, 콜럼버스가 자신이 신대륙을 발견한 일을 비유하기 위해 연회 자리에서 달걀 한쪽을 깨뜨려 식탁에 세운 일은 있지만, 콜럼버스가 최초로 한 일은 아니다. 그것은 당시 민간에서도 행해지던 놀이 가운데 하나였다고 한다.)

배치파일의 가독성

가독성이 왜 좋아야 할까? 그건 배치파일을 사람이 직접 눈으로 보고 해석할 수 있기 때문이다. 그래서 일부에서는 다른 사람이 내가 짠 배치파일을 고치면 엉뚱하게 동작하게 만들기도 하지만, 그것은 그다지 좋은 습관이 아니다. 그럴 경우 자신도 알아보기 힘들기 때문이다. (이럴 경우 실제 소스는 자신이 가지고, 남에게 보여도 되는 복잡한 소스를 컴퓨터에 설치해 두기도 하지만, 번거로운 방법이다.)

비단 배치파일뿐만 아니라 모든 프로그램 소스파일은 사람이 읽기 좋아야 고치기도 편하다. 물론 기계, 곧 컴퓨터에 맞추어 최적화를 시도해도 되지만, 그럴 경우 해당 부분을 모듈(흔히 함수 또는 서브함수)로 만들어 떼어낸 뒤 따로 설명을 붙이는 쪽이 낫다. 그래야 그 모듈은 신경쓰지 않고 전체 맥락에 집중할 수 있기 때문이다.

주석을 달고 가독성을 좋게 해야 하는 또 다른 이유로 배치파일은 한 번 만들어 두면 자주 고치지 않는다는 데 있다. 지금 만든 배치파일을 몇 달 뒤에 또는 몇 년 뒤에 알아볼 수 있을까? 장담할 수 없다. 나중에 고치려고 보면, 처음부터 다시 짜는 만큼 시간이 걸리기 마련이다. 주석을 달아두는 등 가독성을 좋게 해 두었다면 쉽고 빠르게 해결할 일인데 말이다.

가독성 높이기의 기본 : 주석 달기

잘 만들어졌지만, 배치파일 초보에게는 조금 파악하기 힘든 코드를 소개하겠다. 윈도98의 부팅 이미지에 있는 AutoExec.bat 파일의 일부이다.

1. @ECHO OFF
   mshbios
   set EXPAND=YES
   SET DIRCMD=/O:N
   set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
   set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
   cls
   call setramd.bat %LglDrv%
   set temp=c:\
   set tmp=c:\
   path=%RAMD%:\;a:\;%CDROM%:\
   copy command.com %RAMD%:\ > NUL
   set comspec=%RAMD%:\command.com
   copy extract.exe %RAMD%:\ > NUL
   copy readme.txt %RAMD%:\ > NUL

AutoExec.bat 파일의 첫 부분인 위 내용을 보고, 그것이 뜻하는 바를 곧바로 알 수 있다면 어느 정도 경지에 다다른 사람임에 틀림없다. 물론 저 뒷부분은 저렇게 붙어 있지 않다.

그런데 배치파일 초보가 위의 내용을 보고 각 행마다, 또는 여러 행이 어떤 의미를 가지는지 알 수 있을까? 그렇지 않으리라 생각한다. 

그러면 알기 힘든 이유는 무엇일까?

• 우선 주석이 없다.

도스의 명령어를 알더라도 주석이 없어서 알기 힘들다. 전체적으로 쉬운 명령어를 쓰고 있지만, SET 환경 변수를 이용하는 부분에서, 그것이 무슨 역할을 하는지 알기 힘들다. 이는 CALL 명령어에서도 마찬가지이다.

• 각 행간이 너무 촘촘히 붙어 있다.

사람의 눈과 두뇌는 서로 떨어져 있으면 관련이 적다고 여기게 된다. 반대로 서로 붙어 있으면 관련이 좀 더 많다고 여기게 된다. 이런 원리를 생각한다면, 위의 코드는 서로 연관이 적은 코드까지 한데 뭉쳐 있는 셈이다. 앞서 말했듯이 저 부분까지만 저렇게 다닥다닥 붙어 있어서 읽기 힘들게 되어 있고, 뒷부분은 연관이 있는 줄끼리는 붙고, 서로 연관이 적은 곳은 빈 줄을 두어 나누고 있다. 빈 줄을 두면 화면에는 출력되지 않아도 사람이 보기에는 좋다.

조금 수정해 보았다.

1. @ECHO OFF
   rem ====================================
   rem  윈도98 설치 디스크
   rem ====================================
   rem 한글 바이오스 읽어오기
   mshbios
   rem 기본 환경 변수 설정
   set EXPAND=YES
   SET DIRCMD=/O:N
   rem LglDrv 환경 변수 설정
   rem 2행으로 설정한 이유는 한 줄에 적기보다 두 줄로 적어야 보기 좋고,
   rem 명령행의 길이 제한 때문
   set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
   set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
   rem 화면을 지우고, 램드라이브 설정 작업
   cls
   call setramd.bat %LglDrv%
   rem 임시 디렉터리 변수 설정
   set temp=c:\
   set tmp=c:\
   rem 실행경로 변수 설정
   path=%RAMD%:\;a:\;%CDROM%:\
   rem COMSPEC 환경 변수 설정 : 파일 복사 후 설정.
   copy command.com %RAMD%:\ > NUL
   set comspec=%RAMD%:\command.com
   rem 작업을 위한 기본 파일 복사
   copy extract.exe %RAMD%:\ > NUL
   copy readme.txt %RAMD%:\ > NUL

아까보다야 낫지만 그래도 여전하다. 오히려 내용이 늘어서 보기 싫은 점도 있다.

왜? 앞서 말했듯이 코드가 너무 따닥따닥 붙어 있다. 그게 반드시 나쁘다는 말은 아니지만, 너무 붙어 있으면 배치파일 내용을 알기 힘들게 된다.

좀 더 보기 좋게 : 빈 줄 넣기

위의 경우에, 주석이 눈에 잘 들어오지 않는 이유가 코딩 속에 주석이 파묻혀 눈에 잘 띄지 않기 때문이다. 그럴 경우 몇 줄씩 관련 있는 부분을 묶고, 관련이 없는 부분과는 구별할 수 있게 줄 띄기를 하면 된다.

1. @ECHO OFF
   rem ====================================
   rem  윈도98 설치 디스크
   rem ====================================
2.  
3. rem 한글 바이오스 읽어오기
   mshbios
4.  
5. rem 기본 환경 변수 설정
   set EXPAND=YES
   SET DIRCMD=/O:N
6.  
7. rem LglDrv 환경 변수 설정 : 램드라이브를 위한 환경 변수이다.
   rem 2행으로 설정한 이유
8. rem    한 줄에 적기보다 두 줄로 적어야 보기 좋고,
   rem    명령행의 길이 제한 때문 (128 글자)
   set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
   set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
9.  
10. rem 화면을 지운다.
    cls
11.  
12. rem 램드라이브 설정 작업
13. rem setramd.bat : 실제로 램드라이브를 설정해 주는 배치파일
    call setramd.bat %LglDrv%
14.  
15. rem 임시 디렉터리 환경 변수 설정
    set temp=c:\
    set tmp=c:\
    rem 실행경로 환경 변수 설정
    path=%RAMD%:\;a:\;%CDROM%:\
16.  
17. rem COMSPEC 환경 변수 설정 : Command.com 파일 복사 후 설정.
    copy command.com %RAMD%:\ > NUL
    set comspec=%RAMD%:\command.com
    rem 작업을 위한 기본 파일 복사
    copy extract.exe %RAMD%:\ > NUL
    copy readme.txt %RAMD%:\ > NUL

위와 같이 바꾸는 방법은 번거롭다고 여겨질 수도 있다. 하지만 배치파일의 특성상 그 자신이 어떤 일을 할 수도 있지만, 대부분 다른 프로그램에게 일을 시키는 "통로" 역할을 하게 된다. 다시 말해 배치파일 자체에서 일을 하기보다 다른 프로그램에게 일을 시키는 프로그램이다. 그것을 위해 환경을 설정하는 것이야말로 배치파일의 역할이다. 이게 스크립트 언어의 특징이다. (물론 자신이 직접 어떤 역할을 수행하는 스크립트 언어도 존재하지만, 거기에는 대부분 전제 조건이 붙어 있다.)

코드에도 격이 있다. : 들여쓰기

배치파일을 짜다 보면 중요한 코드와 덜 중요한 코드가 있을 수 있다. 또한 한데 묶어서 관리할 부분과 따로 떼어서 관리할 부분이 생기게 된다. 위의 코드도 마찬가지이다.

1. rem 임시 디렉터리 환경 변수 설정

특히 위의 "rem 임시 디렉터리 환경 변수 설정"에서는 더욱 그러하다. 따로 떼어 생각할 부분이 아니기 때문이다. 이럴 경우 해결할 방법은 바로 들여쓰기이다.

앞서 ECHO 명령에서 했던 설명을 또 되살리자.

명령어 다음에, 다른 옵션이 없다면, 빈칸이 있든 없든 같은 의미를 가지게 된다.

여기에 추가하자.

명령어 앞에 다른 명령이 없다면, 빈칸이 있든 없든 같은 의미를 가지게 된다.

이 말은 곧 들여쓰기를 해도 실행 결과는 같다는 뜻이다.

이 말에 맞추어 위의 배치 파일을 고쳐 보자.

1. @ECHO OFF
   rem ====================================
   rem  윈도98 설치 디스크
   rem ====================================
   
   rem 환경 설정
   
   rem 한글 환경 설정
       rem 한글 바이오스 읽어오기
       mshbios
   
   rem 기본 환경 변수 설정 1
       set EXPAND=YES
       SET DIRCMD=/O:N
   
   rem 램드라이브를 위한 환경 설정
   
       rem LglDrv 환경 변수 설정 : 램드라이브를 위한 환경 변수이다.
           rem 2행으로 설정한 이유
               rem    한 줄에 적기보다 두 줄로 적어야 보기 좋고,
               rem    명령행의 길이 제한 때문 (128 글자)
           set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
           set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
   
       rem 화면을 지운다.
           cls
   
       rem 램드라이브 설정 작업
       rem 이 부분은 복잡하므로 다른 배치파일을 불러서 처리.
           rem setramd.bat : 실제로 램드라이브를 설정해 주는 배치파일
           rem 넘겨주는 명령행 인자 %LglDrv%
               call setramd.bat %LglDrv%
   
   rem 기본 환경 변수 설정 2
   
       rem 임시 디렉터리 환경 변수 설정
           set temp=c:\
           set tmp=c:\
       rem 실행경로 환경 변수 설정
           path=%RAMD%:\;a:\;%CDROM%:\
   
       rem COMSPEC 환경 변수 설정
       rem COMSPEC 환경 변수는 명령어 해석기를 지정하는 역할을 한다.
       rem Command.com 파일 복사 후 설정.
           copy command.com %RAMD%:\ > NUL
           set comspec=%RAMD%:\command.com
   
   rem 작업을 위한 파일 복사
   
       rem 압축 파일 작업용 extract.exe : CAB 파일의 압축을 푸는 프로그램
           copy extract.exe %RAMD%:\ > NUL
   
       rem 안내 문서 readme.txt : 안내문이 수록되어 있다.
       copy readme.txt %RAMD%:\ > NUL

실제 실행에서는 처음에 만든 배치파일과 같게 동작한다.

요약

• ECHO를 이용해 화면에 빈 줄을 출력하는 방법과 배치파일을 사람이 읽기 좋게 만드는 법을 설명하였다.

• 기타

  • 명령프롬프트에서 명령어 앞의 공백과 마지막 명령행 인자 및 옵션 뒤의 공백은 무시된다.
  • 문서화되지 않은 방법은 불가피할 때만 써라.

다음 예고

배치파일을 잠시 멈추는 방법과 파라미터를 배치파일에 전달하는 방법에 대해 알아보자.

이 글은 스프링노트에서 작성되었습니다.

들어가며

배치파일에 주석을 다는 법과 화면에 글을 출력하는 법에 대해서 알아보기로 하자. 이때 이때 그래픽 화면 출력은 셸에 포함된 명령어로는 불가능하며, 외부에서 프로그램의 도움을 받아야 한다. 그러므로 배치파일에서 화면 출력이라고 하면, 일반적으로 텍스트 출력만을 가리킨다.

주석 및 기본 출력

배치파일에서는 화면에 출력할 때 ECHO 명령을 사용한다.
앞서 2009/03/02 - [배치파일&스크립트] - 스크립트란 무엇인가? 배치파일이란 무엇인가? 문서에서 만든 배치파일이 바탕화면에 있는 배치파일 폴더에 있다고 가정하고 설명하겠다.

우선 메모장을 연다. 시작 단추 >> 프로그램 >> 보조프로그램 >> 메모장

메모장에 다음과 같이 입력한다.

rem 예제 1 : 화면에 간단한 말을 출력한다.
rem 파일명 : exam01.bat
echo 예제 1.
echo 이 프로그램은 화면 출력 예제 1입니다.
echo 끝.

저장이 끝났으면 메뉴에서 [파일] >> [저장]을 선택하면 아직 이름을 주지 않았으므로 [다른 이름으로 저장]이라는 창이 뜨게 된다. 이때 파일명은 exam01.bat 이라고 하자.
명령 프롬프트를 열어서 결과를 확인하자. 어라! 실행이 되지 않는다. 이것은 명령 프롬프트가 위치한 폴더에 배치파일이 없기 때문이다. 그때는 CD 를 입력한 뒤에 한 칸 띄고 나서 <Tab>을 눌러준다. 그러면 화면에 무언가 변화가 오게 된다. 계속 [Tab]을 눌러 알맞은 폴더( "바탕 화면" )가 나오면 <Enter>를 치기 바란다.

그 뒤에 다시 CD를 누르고 한 칸 띄고 <Tab>을 눌러서 반복한다. 앞서 "배치파일" 폴더에 파일을 넣는다고 했으므로 거기까지 들어가 보자. (여기까지 한/영 변환 키를 한 번도 누르지 않고 왔다. 잘 기억해 두었다가 써먹기 바란다.)

CLS 명령을 입력하고 <Enter>를 눌러 화면을 지우자.

이제 방금 만든 배치파일을 실행해 보자. 이때도 e 또는 ex를 입력하고 <Tab>을 누르면 명령어가 바뀌게 된다. 지난번에 만든 exp.cmd 파일과 이번에 만든 exam01.bat 파일이 존재하고 있으니 그 둘만 자꾸 보여주게 된다. exam01.bat 파일을 실행하면 된다.

exam01.bat 실행 화면

보기가 좋지 않지만 어쨌든 화면 출력을 성공하였다.
하나씩 살펴보자.
첫 줄과 둘째 줄은 REM으로 시작하므로 주석이다. 셋째 줄부터 다섯째 줄까지는 echo를 이용한 화면 출력이다. 그런데 이상한 점은 주석은 자기 자신을 보여주고는 아무런 일도 하지 않았으나, echo는 자신을 보여주고, 해당 출력을 1회씩 하였다. echo는 결국 2번씩 보여준 셈이 된다.

이때 명령 프롬프트에서는 Rem 명령은 Remark (설명하다)에 온 말이며, 아무런 역할도 하지 않는다. 그렇기 때문에 배치파일 안에 주석을 넣는 명령어로 쓰이게 된다.

명령어 반향 감추기 1

앞서 만든 exam01.bat를 고쳐보자. 메모장에서 exam01.bat를 열어서 다음과 같이 고쳐보자.

echo off
rem 예제 2 : 화면에 간단한 말을 출력한다.
rem 파일명 : exam02.bat
echo 예제 2.
echo 이 프로그램은 화면 출력 예제 2입니다.
echo 끝.

[파일] >> [다른 이름으로 저장...]을 눌러 exam02.bat 라는 이름을 주어 저장하자. 명령 프롬프트에서 exam02.bat를 실행하면 아까보다는 깨끗한 결과를 볼 수 있다.

exam02.bat 실행 화면

이때 첫 줄이 중요하다. 아까와는 달리 echo off 라고 명령을 내렸다. echo는 화면에 글자를 출력하는 명령이 아니었나? 얼른 다음과 같이 입력하자.

echo /? <Enter>

친절한 설명이 나와 있다. echo의 기능은 (1) 메시지를 보여주거나 (2) 명령어 반향을 켜거나 끄고(기본값은 켠다), (3) echo만 일력했을 때 반향 설정값을 보여준다.

ECHO 명령어 도움말

예제 1에서 화면이 깨끗하지 못한 이유는 바로 "명령어 반향"이라는 기능이 켜져 있었기 때문이다. 이 기능은 사용자에게 명령어가 입력되었음을 알려주는 기능이다. 이는 사용자에게 작업 내용을 알린다는 측면에서는 매우 유용하다. 그러나 반대로 배치파일에서처럼 출력 결과를 원할 때에는 지저분하게 되어 좋지 않다. 이럴 경우 명령어 반향을 끄면 좋다. 그럴 때 쓰는 명령어가 ECHO OFF 이다. 반대로 ECHO ON 이라고 하면 다시 명령어 반향이 켜지게 된다.

그러나 여전히 echo off 명령 자체는 감추지 못해서 찝찝함이 남는다.

명령어 반향 감추기 2

앞서 만든 exam02.bat를 고쳐보자. 메모장에서 exam02.bat를 열어서 다음과 같이 고쳐보자.

@echo off
rem 예제 3 : 화면에 간단한 말을 출력한다.
rem 파일명 : exam03.bat
echo 예제 3.
echo 이 프로그램은 화면 출력 예제 3입니다.
echo 끝.

[파일] >> [다른 이름으로 저장...]을 눌러 exam03.bat 라는 이름을 주어 저장하자. 명령 프롬프트에서 exam03.bat를 실행하면 아까보다 조금 더 깨끗한 결과를 볼 수 있다.

exam03.bat 실행 화면

이번에도 첫 줄이 중요하다. 아까와는 달리 @echo off 라고 명령을 내렸다. 흠 @ (commat) 표시^[각주:1]에 무언가 있다는 말인데... 이것은 해당 명령어 1개만 반향을 끄라는 말이다. 다시 말해 "echo off 자체의 명령어 반향을 꺼라"라는 의미가 된다.

요약

오늘은 ECHO를 이용해 화면에 글자를 출력하는 법과 REM으로 주석을 붙이는 법에 대해 알아 보았다. REM에 대한 설명은 없지만, "나는 모르겠다."라는 사람은 글을 남기기 바란다.

• 오늘 배운 명령어 : ECHO , REM
• 오늘 배운 용어 : 명령어 반향
• 기타 :
• CD 명령어와 [Tab]을 조합하여 폴더를 이동하는 방법
• @을 이용하여 명령어 끄는 방법

다음 예고

화면 출력에 대해 좀 더 자세히 알아보기로 하자.

말뜻

배치파일에서 이용할 수 있는 명령어란 배치파일에서 불러들여 실행할 수 있는 내부 명령어 또는 외부 명령어를 일컫는다. 내부 명령어는 명령어 셸에 내장된 명령어를 가리키고, 외부 명령어는 실행 파일과 같은 파일로서 존재한다.

실행 파일은 주로 .COM, .EXE, .BAT와 같은 것이 있으며, 윈도NT 계열에서는 .CMD 파일도 쓰인다. 그밖에 윈도 스크립트인 .VBS, .SCF 파일도 실행이 가능하다.

배치파일에서 이용할 수 있는 명령어는 명령 프롬프트에서 "set" 명령을 입력하고 <Enter>를 누르면 보이는 목록에서 PATHEXT를 찾으면 확인할 수 있다.

윈도용 파일 실행

도스를 수박 겉핥기 식으로 배운 사람은 배치파일에서 윈도용 프로그램을 실행할 수 없다고 생각할 수도 있다. 그럼 간단한 실험을 하자.

명령 프롬프트를 열고 다음과 같이 입력한다.

copy con note.cmd <Enter>
notepad.exe <Enter>
pause <Enter>
<Ctrl-Z>

이제 note.cmd를 입력하면 노트패드, 곧 "메모장"이 실행되어야 한다. 둘째 줄에 입력한 pause는 "잠시 멈춤"을 뜻하는 내부 명령어이다. 메모장이 실행되지 않는다면 컴퓨터에서 notepad.exe가 없거나 경로 설정이 되어 있지 않다는 뜻이다.

스크립트 파일 실행

우리가 가장 쉽게 접할 수 있는 스크립트 파일은 explorer.scf 파일이다. 이 파일은 윈도 폴더에 있다.
위의 PATHEXT에는 없지만 SCF 파일도 실행이 가능하다.

명령 프롬프트를 열고 다음과 같이 입력한다.

copy con exp.cmd <Enter>
explorer.scf <Enter>
pause <Enter>
<Ctrl-Z>

자신의 윈도XP가 정상이라면 윈도 탐색기가 실행되어야 한다.

또한 .SCF 스크립트 외에 .MSC 파일도 실행할 수 있다.

copy con df.cmd <Enter>
dfrg.msc <Enter>
pause <Enter>
<Ctrl-Z>

역시 자신의 윈도XP가 정상이라면 디스크 조각 모음이라는 애플릿이 실행되어야 한다. 이때 .MSC 파일은 스크립트 파일은 아니다. 노트패드에서 읽어 들이면, 그 파일은 XML 파일임을 알 수 있다. 윈도가 특별하게 작동시키는 파일이다.

다음 예고

주석 다는 법과 화면에 메시지 출력하는 법을 알아보기로 하자.